Meeting Pearls 4/Meeting Pearls Vol. IV (1996)(GTI - Schatztruhe)[!].iso/Pearls/etech/GALer20/Install

Text File | 1996-04-07 | 13KB | 454 lines

; $VER: GALer Install, Copyright ©1996 Christian Habermann
;
;     GALer, All Rights Reserved.
;
;     GALer ©1991-1996 Christian Habermann
;     Reqtools ©1991-1995 Nico François
;     MUI ©1992-1994 Stefan Stuntz


(delopts "oknodelete" "force" "askuser")



;**************************************************************************
;** English strings, this is the default language                        **
;**************************************************************************

    (set #introduction
        (cat "This program installs \n\n GALer\n\n"
             "on your harddisk.\n\n"
             "Select \"Proceed\" to continue or\n"
            "\"Abort Install\" to cancel."
        )
    )


    (set #badOS "\n Sorry, this package requires OS V2.04 or better.\n")


    (set #dest_dir
        (cat "Please select a directory in which GALer\nshould be installed.\n"
             "A subdirecory \"GALer\" will be created automatically!"
        )
    )


    (set #dest_dir_help
        (cat "\nSelect a directory on your hard disk in which you want to get "
             "GALer installed. In this directory a directory \"GALer\" will be "
             "created, in which the files will be copied."
        )
    )


    (set #already_installed
        (cat "\nA version of GALer is already installed. "
             "Do you want to install GALer V2.0."
        )
    )

    (set #already_installed_help
        (cat "\nIf you select \"Yes\", "
             "the existing version will be replaced with GALer V2.0.\n"
             "If you select \"No\", the installation will be aborted."
        )
    )


    (set #install_components
        (cat "\nPlease select which components you want to install."
        )
    )

    (set #install_components_help
        (cat "\nHere you can select which components of GALer you want to install"
             "The components are:\n\n"
             "GALer and manual: The programs and the manual will be installed.\n\n"
             "Examples: Some examples will be installed.\n\n"
             "PCB-Layout: The Gerber- and PostScript files of a PCB will be installed.\n\n"
             "Source-Code: The whole source-code of the GALer project will be installed."
        )
    )


    (set #inst_GALer
        (cat "GALer and manual"
        )
    )

    (set #inst_examples
        (cat "Examples"
        )
    )

    (set #inst_layout
        (cat "PCB-Layout"
        )
    )

    (set #inst_source
        (cat "Source-Code"
        )
    )



    (set #ask_dvi_manual
        (cat "\nDo you want to install a DVI version (TeX) of the manual?"
        )
    )

    (set #ask_dvi_manual_help
        (cat "\nTo use the DVI version of the manual you need TeX (e.g. PasTeX). "
             "Without this you can't display the manual."
        )
    )



    (set #readme_file "ReadMe")
    (set #hardware_file "Hardware1.3E")
    (set #manual_guide_file "Doc/GALer_E.guide")
    (set #manual_dvi_file "")



;**************************************************************************
;** German strings                                                       **
;**************************************************************************

(if (= @language "deutsch") (

    (set #introduction
        (cat "Mit diesem Programm wird \n\n GALer\n\n auf eine "
             "Festplatte installiert.\n\n"
             "Drücken Sie \"Proceed\", um weiterzumachen oder\n"
             "\"Abort Install\", um die Installation abzubrechen."
        )
    )


    (set #badOS "\n Sorry, dieses Programm benötigt OS V2.04 oder höher.\n")


    (set #dest_dir
        (cat "Bitte wählen Sie das Verzeichnis aus, in das GALer\ninstalliert werden soll!\n"
             "Ein Unterverzeichnis \"GALer\" wird automatisch erzeugt!"
        )
    )

    (set #dest_dir_help
        (cat "\nWählen Sie einfach das Verzeichnis aus, in das GALer installiert werden soll. "
             "In diesem Verzeichnis wird dann ein Unterverzeichnis Namens \"GALer\" erzeugt, "
             "in das das Program und andere Dateien kopiert werden."
        )
    )


    (set #already_installed
        (cat "\nEine Version von GALer ist bereits installiert. "
             "Soll diese durch GALer 2.0 ersetzt werden?"
        )
    )

    (set #already_installed_help
        (cat "\nGALer ist bereits installiert. Wenn Sie \"Yes\" anwählen, "
             "wird GALer V2.0 über Ihre alte Installation kopiert.\n"
             "Wenn Sie \"No\" anwählen, wird die Installation abgebrochen."
        )
    )


    (set #install_components
        (cat "\nBitte wählen Sie aus, was alles installiert werden soll."
        )
    )

    (set #install_components_help
        (cat "\nHier können Sie auswählen, welche Komponenten installiert werden "
             "sollen. Im einzelnen sind das: \n\n"
             "GALer mit Anleitung: Es wird GALer und die dazugehörige Anleitung "
             "installiert.\n\n"
             "Beispiele: Es werden verschiedene Beispiele installiert.\n\n"
             "PCB-Layout: Es werden die Gerber- und PostScript-Files eines "
             "Platinen-Layouts installiert.\n\n"
             "Source-Code: Es wird der komplette Source-Code des GALer-Projekts "
             "installiert."
        )
    )


    (set #inst_GALer
        (cat "GALer mit Anleitung"
        )
    )

    (set #inst_examples
        (cat "Beispiele"
        )
    )

    (set #inst_layout
        (cat "PCB-Layout"
        )
    )

    (set #inst_source
        (cat "Source-Code"
        )
    )



    (set #ask_dvi_manual
        (cat "\nEs gibt eine DVI-Version (LaTeX) der Anleitung. "
             "Wenn Sie die Möglichkeit haben, DVI-Files anzuzeigen "
             "oder auszudrucken, wird dringend empfohlen, die DVI-Version "
             "zu installieren. Diese Anleitung ist mit vielen erklärenden "
             "Bildern versehen, die im Guide-File fehlen.\n"
             "Soll die DVI-Version der Anleitung installiert werden? "
             "Wenn ja, lesen bitte nach dem Installations-Prozeß unbedingt "
             "das LiesMich-File im Doc-Verzeichnis, bevor Sie die DVI-Version "
             "anzeigen bzw. ausdrucken (WICHTIG!!!)"
        )
    )

    (set #ask_dvi_manual_help
        (cat "\nBei DVI-Files handelt es sich um spezielle Text-Files, die "
             "mit dem Schriftsatzprogramm TeX erstellt wurden. Diese Files "
             "können nur mit einem speziellen Anzeigeprogramm betrachtet werden "
             "(z.B. ShowDVI). Wenn Sie eine TeX-Version installiert haben (z.B. "
             "PasTeX), so wird die Installation der DVI-Version der Anleitung "
             "empfohlen. Die Qualität der DVI-Version ist erheblich besser "
             "als die der \"normalen\" Text-Version."
        )
    )


    (set #readme_file "LiesMich")
    (set #hardware_file "Hardware1.3D")
    (set #manual_guide_file "Doc/GALer_D.guide")
    (set #manual_dvi_file "Doc/GALer_D.dvi")
    (set #manual_doc_dvi_file "Doc/LiesMich")

))




;**************************************************************************
;** Main - start with actions                                            **
;**************************************************************************

(message #introduction)
(welcome)

(complete 0)



(if (< (/ (getversion) 65536) 37)           ; sure that we are running under
    (                                       ; OS V2.04 or better?
        (message #badOS)

        (exit (quiet))
    )
)




(set target                                 ; select the destination directory
    (askdir
        (prompt #dest_dir)
        (help   #dest_dir_help)
        (default "Sys:")                    ; SYS: does exist always
    )
)


(set @default-dest target)                  ; set the default destination



(if (exists (tackon target "GALer"))        ; does GALer already exist?
    (  message (#already_installed)
               (help #already_installed_help)   ; yes, then make it public
    )
    (  makedir (tackon target "GALer")          ; no, then create the directory
    )
)



(set inst (askoptions (prompt #install_components)        ; ask what to install
                      (help   #install_components_help)
                      (default -1)
                      (choices  #inst_GALer
                                #inst_examples
                                #inst_layout
                                #inst_source)
     )
)



                            ; ok, now we know what to install, so do it...

(if (BITAND inst 1)                               ; install program and manual?
    (
        (copyfiles (source "")                      ; install programms
                   (dest (tackon target "GALer"))
                   (choices "GALer"
                            "GALerTest"
                            #readme_file
                            #hardware_file)
                   (infos)
        )

        (complete 25)


        (if (NOT (exists (tackon target "GALer/Doc")) )
            (makedir (tackon target "GALer/Doc"))
        )

        (copyfiles (source #manual_guide_file)              ; install GALer.guide
                   (dest (tackon target "GALer/Doc"))
                   (newname "GALer.guide")
                   (infos)
        )

        (copyfiles (source "Doc.info")
                   (dest (tackon target "GALer"))
        )

        (complete 35)


        (if (<> #manual_dvi_file "")               ; is there a dvi-file?
            (
                (set result (askbool (prompt #ask_dvi_manual)
                                     (help   #ask_dvi_manual_help))
                )

                (if (= result 1)                    ; install GALer.dvi
                    (
                        (copyfiles (source #manual_dvi_file)
                                   (dest (tackon target "GALer/Doc"))
                                   (newname "GALer.dvi")
                                   (infos))

                        (copyfiles (source #manual_doc_dvi_file)
                                   (dest (tackon target "GALer/Doc"))
                                   (newname "LiesMich")
                                   (infos))
                    )
                )
            )
        )

        (complete 48)


        (copyfiles (source "s")                     ; install config-file
                   (dest "s:")
                   (choices "GALer.config")
                   (infos)
                   (nogauge)
        )


        (if (= @language "deutsch")                 ; install catalogs
            (
                (if (exists "LOCALE:" (noreq))
                    (copyfiles (source "Catalogs/deutsch")
                               (dest "LOCALE:catalogs/deutsch")
                               (all)
                               (infos)
                    )

                )
            )
        )


        (copylib (source "libs/reqtools.library")       ; install libraries
                 (dest "libs:")
        )



    )
)

(complete 50)


(if (BITAND inst 2)                                 ; install examples?
    (
        (if (NOT (exists (tackon target "GALer/Examples")) )
            (makedir (tackon target "GALer/Examples"))
        )

        (copyfiles (source "Examples.info")
                   (dest (tackon target "GALer"))
        )

        (copyfiles (source "Examples")
                   (dest (tackon target "GALer/Examples"))
                   (all)
                   (infos)
        )
    )
)

(complete 60)



(if (BITAND inst 4)                                 ; install PCB?
    (
        (if (NOT (exists (tackon target "GALer/Layout")))
            (makedir (tackon target "GALer/Layout"))
        )

        (copyfiles (source "Layout.info")
                   (dest (tackon target "GALer"))
        )

        (copyfiles (source "Layout")
                   (dest (tackon target "GALer/Layout"))
                   (all)
                   (infos)
        )
    )
)

(complete 75)



(if (BITAND inst 8)                                 ; install source code?
    (
        (if (NOT (exists (tackon target "GALer/Source")))
            (makedir (tackon target "GALer/Source"))
        )

        (copyfiles (source "Source.info")
                   (dest (tackon target "GALer"))
        )

        (copyfiles (source "Source")
                   (dest (tackon target "GALer/Source"))
                   (all)
                   (infos)
        )
    )
)

(complete 100)